Backup log files

Question

Hello!

I need to store all Adaxes log files to be able to inspect old logs and find out who performed certain operations. Can I back up log files?

Answer 1

Update 2015

Adaxes logs are included into the configuration backup. For information on how to make a backup, have a look at the following help article: https://www.adaxes.com/help/BackupRestoreConfiguration.

Original

You can back up Adaxes log files using the following VB script:

AdaxesServiceHost = "localhost"
' If the username and password is Empty, the current user is used
Username = Empty
Password = Empty
' The parameter defines time period (in days since now) log records are backed up.
' If the parameter is 0 all records will be backed up.
NumberOfDaysToBackup = 0
' Contains file where log records will be written
BackupFilePath = "Backup.txt"

'Open the Adaxes namespace object
Set ns = GetObject("Adaxes:")
'Get the Adaxes service
Set admService = ns.GetService(AdaxesServiceHost, Username, Password)
'Get the ADsPath of the Service Log object
serviceLogPath = admService.Backend.GetConfigurationContainerPath("ServiceLog")
'Open the Service Log object
Set admServiceLog = admService.OpenObject(serviceLogPath, Username, Password, 0)
'Get the General log object
Set admGeneralLog = admServiceLog.GeneralLog
If NumberOfDaysToBackup <> 0 Then
    admGeneralLog.StartDateTime = DateAdd("d", -NumberOfDaysToBackup, Now())
    admGeneralLog.EndDateTime = Now()
End If
' Get log object
Set admLog = admGeneralLog.Log
Set admRecords = admLog.GetPage(0)
recordsCount = admRecords.Count
'Open the file and write all records into it
Set fso = CreateObject("Scripting.FileSystemObject")
Set textStream = fso.OpenTextFile(BackupFilePath, 2, True)
For index = 0 To recordsCount - 1
    Set admRecord = admRecords.GetObject(index)
    textStream.WriteLine "Start Time: " & admRecord.StartTime
    textStream.WriteLine "Completion Time: " & admRecord.CompletionTime
    textStream.WriteLine "Initiator: " & admRecord.Initiator.Name
    textStream.WriteLine "Target Object GUID: " & admRecord.TargetObjectGuid
    textStream.WriteLine "Operation Description: " & admRecord.Description
    textStream.WriteLine
Next